#pragma rtGlobals=1		// Use modern global access method.

//@ This function is to use with James' progam to extract and export waves and matrices for organic analysis. 
//@ Codes written by James Allan, modified by Qi Zhang
function org_mats(maskstr)
	string maskstr
	variable n,i
	fraglist_convert_new("frag_organic","org_tmp")
	frag_matrix($"org_tmp","org_matrix",3)
	wave /z maskwav=$maskstr
	wave /z org_matrix,l_series
	wave /z mssd=root:msdata:mssdiff,mssd_err=root:msdata:mssdiff_err
	n=(numpnts(l_series))
	make /o/n=(n,dimsize(org_matrix,0)) organics_MS,organics_MS_err
	make /o/n=(dimsize(mssd,1),dimsize(mssd,1)) org_tmp1=org_matrix[q][p]
	make /o/n=(dimsize(mssd,0),dimsize(mssd,1)) org_tmp4=numtype(mssd)?0:mssd
	ams_stat_upd("Mutiplying matrixes")
	matrixop /o org_tmp2=org_tmp4 x org_tmp1
	org_tmp4=numtype(mssd_err)?0:(mssd_err^2)
	matrixop /o org_tmp3=org_tmp4 x (org_tmp1*org_tmp1)
	org_tmp3=sqrt(org_tmp3)
	
//	make /o/n=(dimsize(org_matrix,0)) org_tmp1,org_tmp1_err
	ams_stat_upd("Transferring data.")
	for (i=0;i<n;i+=1)
		if (numtype(l_series[i]) || (waveexists(maskwav) && !maskwav[i]))
			organics_MS[i][]=nan
			organics_MS_err[i][]=nan
		else
			organics_MS[i][]=org_tmp2[l_series[i]][q]
			organics_MS_err[i][]=org_tmp3[l_series[i]][q]
//			org_tmp1=mssd[l_series[i]][p]
//			org_tmp1_err=mssd_err[l_series[i]][p]
//			ms_spec(org_tmp1,org_matrix,"org_tmp2")
//			wave org_tmp2,org_tmp2_err
//			organics_MS[i][]=org_tmp2[q]
//			organics_MS_err[i][]=org_tmp2_err[q]
		endif
		ams_prog_upd(100*i/n)
	endfor
	nvar ms2_calmass
	wave ioneff_ref,flowrate,corr_fac
	organics_MS*=corr_fac[p]*(ms2_calmass/na)*1e12/(ioneff_ref[p]*flowrate[p])
	organics_MS_err*=corr_fac[p]*(ms2_calmass/na)*1e12/(ioneff_ref[p]*flowrate[p])
	wave/T spec_list
	wave IEfac_list, CEfac_list
	organics_MS /= (IEfac_list[findstr(spec_list, "org", 2)] * CEfac_list[findstr(spec_list, "org", 2)])
	organics_MS_err /= (IEfac_list[findstr(spec_list, "org", 2)] * CEfac_list[findstr(spec_list, "org", 2)])
	ams_prog_upd(100)
	killwaves org_tmp1,org_tmp2,org_tmp3,org_tmp4
	ams_stat_upd("Done")
	if (waveexists(org) && waveexists(SO4) && waveexists(NO3) && waveexists(NH4) && waveexists(chl))
		Save/T/M="\r\n" t_series, rn_series, org, SO4, NO3, NH4, Chl, Organics_MS, Organics_MS_err as "WavesMatricesForOrganicAnalysis.itx"
	elseif (waveexists(organics) && waveexists(sulphate) && waveexists(nitrate) && waveexists(ammonium) && waveexists(chloride))
		Save/T/M="\r\n" t_series, rn_series, organics, sulphate, nitrate, ammonium, chlordie, Organics_MS, Organics_MS_err as "WavesMatricesForOrganicAnalysis.itx"
	endif
end

function gen_mats(maskstr,speclist,corrstr)
	string maskstr,speclist,corrstr
	variable n,i,m,j
	string spec
	wave /z maskwav=$maskstr,excorr=$corrstr
	wave /z mssd=root:msdata:mssdiff,mssd_err=root:msdata:mssdiff_err,l_series
	n=numpnts(l_series)
	m=itemsinlist(speclist)
	for (j=0;j<m;j+=1)
		spec=stringfromlist(j,speclist)
		ams_stat_upd("Doing "+spec)
		wave /z matrix=$(spec+"_matrix")
		make /o/n=(n,dimsize(matrix,0)) $(spec+"_specs"),$(spec+"specs_err")
		wave specs=$(spec+"_specs"),specs_err=$(spec+"specs_err")
		make /o/n=(dimsize(matrix,0)) mat_tmp1,mat_tmp1_err
		for (i=0;i<n;i+=1)
			if (numtype(l_series[i]) || (waveexists(maskwav) && !maskwav[i]))
				specs[i][]=nan
				specs_err[i][]=nan
			else
				mat_tmp1=mssd[l_series[i]][p]
				mat_tmp1_err=mssd_err[l_series[i]][p]
				ms_spec(mat_tmp1,matrix,"mat_tmp2")
				wave mat_tmp2,mat_tmp2_err
				specs[i][]=mat_tmp2[q]
				specs_err[i][]=mat_tmp2_err[q]
			endif
			ams_prog_upd(100*(j+(i/n))/m)
		endfor
		nvar ms2_calmass
		wave ioneff_ref,flowrate,corr_fac
		specs*=corr_fac[p]*(ms2_calmass/na)*1e12/(ioneff_ref[p]*flowrate[p])
		specs_err*=corr_fac[p]*(ms2_calmass/na)*1e12/(ioneff_ref[p]*flowrate[p])
		if (waveexists(excorr))
			specs*=excorr
			specs_err*=excorr
		endif
	endfor
	killwaves /z mat_tmp1, mat_tmp1_err, mat_tmp2, mat_tmp2_err
	ams_stat_upd("Done.")
	ams_prog_upd(100)
end